// Face3D - Based on Zoom by REAS <http://reas.com>
// 
// Author: Jorge Cardoso
// http://jorgecardoso.org
//
// 2 July 2005

/* window size  */
int windowWidth = 400;
int windowHeight = 250;


PImage a;

int[][] aPixels;

/* Resolution of the image  */
int res = 2;

/* current rotation angle  */
float rotX = 0;
float rotY = 0;

/* origin of the image on screen  */
int originX;
int originY;

void setup() 
{
  size(windowWidth, windowHeight, P3D);
  noFill();
  stroke(255);
  
  a = loadImage("foto.jpg");
  
  aPixels = new int[a.width][a.height];
  
  /* center image on screen  */
  originX = (width - a.width)/2;
  originY = (height - a.height)/2;
  
  /* copy image to array  */
  for(int i=0; i<a.height; i++) {
    for(int j=0; j<a.width; j++) {
      aPixels[j][i] = a.pixels[i*a.width+j];
    }
  }
}

void draw() 
{
  background(0);

  /* rotate around the center of the screen, a bit to the back */
  translate(windowWidth/2, windowHeight/2, -100);
  rotateX(rotX);
  rotateY(rotY);
  rotX = (rotX + 0.05) %(2*PI);
  rotY = (rotY + 0.03) %(2*PI);
  translate(-windowWidth/2, -windowHeight/2, 0);
  
  /* draw the image as a set of 3d lines*/
  float rr, gg, bb, tt;
  for(int i=0; i<a.height; i+=res) {
    for(int j=0; j<a.width; j+=res) {
      rr = red(aPixels[j][i]); 
      gg = green(aPixels[j][i]);
      bb = blue(aPixels[j][i]);
      tt = rr+gg+bb;
      stroke(rr, gg, gg);
      line(j+originX, i+originY, tt/10-20, j+originX, i+originY, tt/10 );
    }
  }
}

/* change 'resolution'  */
void keyPressed() {
    if(key == '1') {
        res = 1;
    } else if (key == '2') {
        res = 2; 
    } else if (key == '3') {
        res = 3;
    } else if (key == '4') {
        res = 4;
    } else if (key == '5') {
        res = 5;
    }
}